SM0 She11

Path: / / usr / share / cmake3 / Modules

Full Path (server): /usr/share/cmake3/Modules

📄 AddFileDependencies.cmake [E] [D]
📁 AndroidTestUtilities Open [D]
📄 AndroidTestUtilities.cmake [E] [D]
📄 BasicConfigVersion-AnyNewerVersion.cmake.in [E] [D]
📄 BasicConfigVersion-ExactVersion.cmake.in [E] [D]
📄 BasicConfigVersion-SameMajorVersion.cmake.in [E] [D]
📄 BasicConfigVersion-SameMinorVersion.cmake.in [E] [D]
📄 BundleUtilities.cmake [E] [D]
📄 CMake.cmake [E] [D]
📄 CMakeASM-ATTInformation.cmake [E] [D]
📄 CMakeASMCompiler.cmake.in [E] [D]
📄 CMakeASMInformation.cmake [E] [D]
📄 CMakeASM_MASMInformation.cmake [E] [D]
📄 CMakeASM_NASMInformation.cmake [E] [D]
📁 CMakeAddFortranSubdirectory Open [D]
📄 CMakeAddFortranSubdirectory.cmake [E] [D]
📄 CMakeAddNewLanguage.txt [E] [D]
📄 CMakeBackwardCompatibilityC.cmake [E] [D]
📄 CMakeBackwardCompatibilityCXX.cmake [E] [D]
📄 CMakeBorlandFindMake.cmake [E] [D]
📄 CMakeBuildSettings.cmake.in [E] [D]
📄 CMakeCCompiler.cmake.in [E] [D]
📄 CMakeCCompilerABI.c [E] [D]
📄 CMakeCCompilerId.c.in [E] [D]
📄 CMakeCInformation.cmake [E] [D]
📄 CMakeCSharpCompiler.cmake.in [E] [D]
📄 CMakeCSharpCompilerId.cs.in [E] [D]
📄 CMakeCSharpInformation.cmake [E] [D]
📄 CMakeCUDACompiler.cmake.in [E] [D]
📄 CMakeCUDACompilerABI.cu [E] [D]
📄 CMakeCUDACompilerId.cu.in [E] [D]
📄 CMakeCUDAInformation.cmake [E] [D]
📄 CMakeCXXCompiler.cmake.in [E] [D]
📄 CMakeCXXCompilerABI.cpp [E] [D]
📄 CMakeCXXCompilerId.cpp.in [E] [D]
📄 CMakeCXXInformation.cmake [E] [D]
📄 CMakeCheckCompilerFlagCommonPatterns.cmake [E] [D]
📄 CMakeCommonLanguageInclude.cmake [E] [D]
📄 CMakeCompilerABI.h [E] [D]
📄 CMakeCompilerIdDetection.cmake [E] [D]
📄 CMakeConfigurableFile.in [E] [D]
📄 CMakeDependentOption.cmake [E] [D]
📄 CMakeDetermineASM-ATTCompiler.cmake [E] [D]
📄 CMakeDetermineASMCompiler.cmake [E] [D]
📄 CMakeDetermineASM_MASMCompiler.cmake [E] [D]
📄 CMakeDetermineASM_NASMCompiler.cmake [E] [D]
📄 CMakeDetermineCCompiler.cmake [E] [D]
📄 CMakeDetermineCSharpCompiler.cmake [E] [D]
📄 CMakeDetermineCUDACompiler.cmake [E] [D]
📄 CMakeDetermineCXXCompiler.cmake [E] [D]
📄 CMakeDetermineCompileFeatures.cmake [E] [D]
📄 CMakeDetermineCompiler.cmake [E] [D]
📄 CMakeDetermineCompilerABI.cmake [E] [D]
📄 CMakeDetermineCompilerId.cmake [E] [D]
📄 CMakeDetermineFortranCompiler.cmake [E] [D]
📄 CMakeDetermineJavaCompiler.cmake [E] [D]
📄 CMakeDetermineOBJCCompiler.cmake [E] [D]
📄 CMakeDetermineOBJCXXCompiler.cmake [E] [D]
📄 CMakeDetermineRCCompiler.cmake [E] [D]
📄 CMakeDetermineSwiftCompiler.cmake [E] [D]
📄 CMakeDetermineSystem.cmake [E] [D]
📄 CMakeDetermineVSServicePack.cmake [E] [D]
📄 CMakeExpandImportedTargets.cmake [E] [D]
📄 CMakeExportBuildSettings.cmake [E] [D]
📄 CMakeExtraGeneratorDetermineCompilerMacrosAndIncludeDirs.cmake [E] [D]
📄 CMakeFindBinUtils.cmake [E] [D]
📄 CMakeFindCodeBlocks.cmake [E] [D]
📄 CMakeFindDependencyMacro.cmake [E] [D]
📄 CMakeFindEclipseCDT4.cmake [E] [D]
📄 CMakeFindFrameworks.cmake [E] [D]
📄 CMakeFindJavaCommon.cmake [E] [D]
📄 CMakeFindKate.cmake [E] [D]
📄 CMakeFindPackageMode.cmake [E] [D]
📄 CMakeFindSublimeText2.cmake [E] [D]
📄 CMakeFindWMake.cmake [E] [D]
📄 CMakeFindXCode.cmake [E] [D]
📄 CMakeForceCompiler.cmake [E] [D]
📄 CMakeFortranCompiler.cmake.in [E] [D]
📄 CMakeFortranCompilerABI.F [E] [D]
📄 CMakeFortranCompilerId.F.in [E] [D]
📄 CMakeFortranInformation.cmake [E] [D]
📄 CMakeGenericSystem.cmake [E] [D]
📄 CMakeGraphVizOptions.cmake [E] [D]
📄 CMakeIOSInstallCombined.cmake [E] [D]
📄 CMakeImportBuildSettings.cmake [E] [D]
📄 CMakeInitializeConfigs.cmake [E] [D]
📄 CMakeJOMFindMake.cmake [E] [D]
📄 CMakeJavaCompiler.cmake.in [E] [D]
📄 CMakeJavaInformation.cmake [E] [D]
📄 CMakeLanguageInformation.cmake [E] [D]
📄 CMakeMSYSFindMake.cmake [E] [D]
📄 CMakeMinGWFindMake.cmake [E] [D]
📄 CMakeNMakeFindMake.cmake [E] [D]
📄 CMakeNinjaFindMake.cmake [E] [D]
📄 CMakeOBJCCompiler.cmake.in [E] [D]
📄 CMakeOBJCCompilerABI.m [E] [D]
📄 CMakeOBJCCompilerId.m.in [E] [D]
📄 CMakeOBJCInformation.cmake [E] [D]
📄 CMakeOBJCXXCompiler.cmake.in [E] [D]
📄 CMakeOBJCXXCompilerABI.mm [E] [D]
📄 CMakeOBJCXXCompilerId.mm.in [E] [D]
📄 CMakeOBJCXXInformation.cmake [E] [D]
📄 CMakePackageConfigHelpers.cmake [E] [D]
📄 CMakeParseArguments.cmake [E] [D]
📄 CMakeParseImplicitIncludeInfo.cmake [E] [D]
📄 CMakeParseImplicitLinkInfo.cmake [E] [D]
📄 CMakePlatformId.h.in [E] [D]
📄 CMakePrintHelpers.cmake [E] [D]
📄 CMakePrintSystemInformation.cmake [E] [D]
📄 CMakePushCheckState.cmake [E] [D]
📄 CMakeRCCompiler.cmake.in [E] [D]
📄 CMakeRCInformation.cmake [E] [D]
📄 CMakeSwiftCompiler.cmake.in [E] [D]
📄 CMakeSwiftInformation.cmake [E] [D]
📄 CMakeSystem.cmake.in [E] [D]
📄 CMakeSystemSpecificInformation.cmake [E] [D]
📄 CMakeSystemSpecificInitialize.cmake [E] [D]
📄 CMakeTestASM-ATTCompiler.cmake [E] [D]
📄 CMakeTestASMCompiler.cmake [E] [D]
📄 CMakeTestASM_MASMCompiler.cmake [E] [D]
📄 CMakeTestASM_NASMCompiler.cmake [E] [D]
📄 CMakeTestCCompiler.cmake [E] [D]
📄 CMakeTestCSharpCompiler.cmake [E] [D]
📄 CMakeTestCUDACompiler.cmake [E] [D]
📄 CMakeTestCXXCompiler.cmake [E] [D]
📄 CMakeTestCompilerCommon.cmake [E] [D]
📄 CMakeTestFortranCompiler.cmake [E] [D]
📄 CMakeTestGNU.c [E] [D]
📄 CMakeTestJavaCompiler.cmake [E] [D]
📄 CMakeTestOBJCCompiler.cmake [E] [D]
📄 CMakeTestOBJCXXCompiler.cmake [E] [D]
📄 CMakeTestRCCompiler.cmake [E] [D]
📄 CMakeTestSwiftCompiler.cmake [E] [D]
📄 CMakeUnixFindMake.cmake [E] [D]
📄 CMakeVerifyManifest.cmake [E] [D]
📄 CPack.cmake [E] [D]
📄 CPackComponent.cmake [E] [D]
📄 CPackIFW.cmake [E] [D]
📄 CPackIFWConfigureFile.cmake [E] [D]
📄 CSharpUtilities.cmake [E] [D]
📄 CTest.cmake [E] [D]
📄 CTestCoverageCollectGCOV.cmake [E] [D]
📄 CTestScriptMode.cmake [E] [D]
📄 CTestTargets.cmake [E] [D]
📄 CTestUseLaunchers.cmake [E] [D]
📄 CheckCCompilerFlag.cmake [E] [D]
📄 CheckCSourceCompiles.cmake [E] [D]
📄 CheckCSourceRuns.cmake [E] [D]
📄 CheckCXXCompilerFlag.cmake [E] [D]
📄 CheckCXXSourceCompiles.cmake [E] [D]
📄 CheckCXXSourceRuns.cmake [E] [D]
📄 CheckCXXSymbolExists.cmake [E] [D]
📄 CheckForPthreads.c [E] [D]
📄 CheckFortranCompilerFlag.cmake [E] [D]
📄 CheckFortranFunctionExists.cmake [E] [D]
📄 CheckFortranSourceCompiles.cmake [E] [D]
📄 CheckFortranSourceRuns.cmake [E] [D]
📄 CheckFunctionExists.c [E] [D]
📄 CheckFunctionExists.cmake [E] [D]
📁 CheckIPOSupported Open [D]
📄 CheckIPOSupported.cmake [E] [D]
📄 CheckIncludeFile.c.in [E] [D]
📄 CheckIncludeFile.cmake [E] [D]
📄 CheckIncludeFile.cxx.in [E] [D]
📄 CheckIncludeFileCXX.cmake [E] [D]
📄 CheckIncludeFiles.cmake [E] [D]
📄 CheckLanguage.cmake [E] [D]
📄 CheckLibraryExists.cmake [E] [D]
📄 CheckLibraryExists.lists.in [E] [D]
📄 CheckOBJCCompilerFlag.cmake [E] [D]
📄 CheckOBJCSourceCompiles.cmake [E] [D]
📄 CheckOBJCSourceRuns.cmake [E] [D]
📄 CheckOBJCXXCompilerFlag.cmake [E] [D]
📄 CheckOBJCXXSourceCompiles.cmake [E] [D]
📄 CheckOBJCXXSourceRuns.cmake [E] [D]
📄 CheckPIESupported.cmake [E] [D]
📄 CheckPrototypeDefinition.c.in [E] [D]
📄 CheckPrototypeDefinition.cmake [E] [D]
📄 CheckSizeOf.cmake [E] [D]
📄 CheckStructHasMember.cmake [E] [D]
📄 CheckSymbolExists.cmake [E] [D]
📄 CheckTypeSize.c.in [E] [D]
📄 CheckTypeSize.cmake [E] [D]
📄 CheckTypeSizeMap.cmake.in [E] [D]
📄 CheckVariableExists.c [E] [D]
📄 CheckVariableExists.cmake [E] [D]
📁 Compiler Open [D]
📁 CompilerId Open [D]
📄 Dart.cmake [E] [D]
📄 DartConfiguration.tcl.in [E] [D]
📄 DeployQt4.cmake [E] [D]
📄 Documentation.cmake [E] [D]
📄 DummyCXXFile.cxx [E] [D]
📄 ExternalData.cmake [E] [D]
📄 ExternalData_config.cmake.in [E] [D]
📄 ExternalProject-download.cmake.in [E] [D]
📄 ExternalProject-verify.cmake.in [E] [D]
📄 ExternalProject.cmake [E] [D]
📄 FLTKCompatibility.cmake [E] [D]
📄 FeatureSummary.cmake [E] [D]
📁 FetchContent Open [D]
📄 FetchContent.cmake [E] [D]
📄 FindALSA.cmake [E] [D]
📄 FindASPELL.cmake [E] [D]
📄 FindAVIFile.cmake [E] [D]
📄 FindArmadillo.cmake [E] [D]
📄 FindBISON.cmake [E] [D]
📄 FindBLAS.cmake [E] [D]
📄 FindBZip2.cmake [E] [D]
📄 FindBacktrace.cmake [E] [D]
📄 FindBoost.cmake [E] [D]
📄 FindBullet.cmake [E] [D]
📄 FindCABLE.cmake [E] [D]
📁 FindCUDA Open [D]
📄 FindCUDA.cmake [E] [D]
📄 FindCUDAToolkit.cmake [E] [D]
📄 FindCURL.cmake [E] [D]
📄 FindCVS.cmake [E] [D]
📄 FindCoin3D.cmake [E] [D]
📄 FindCups.cmake [E] [D]
📄 FindCurses.cmake [E] [D]
📄 FindCxxTest.cmake [E] [D]
📄 FindCygwin.cmake [E] [D]
📄 FindDCMTK.cmake [E] [D]
📄 FindDart.cmake [E] [D]
📄 FindDevIL.cmake [E] [D]
📄 FindDoxygen.cmake [E] [D]
📄 FindEXPAT.cmake [E] [D]
📄 FindEnvModules.cmake [E] [D]
📄 FindFLEX.cmake [E] [D]
📄 FindFLTK.cmake [E] [D]
📄 FindFLTK2.cmake [E] [D]
📄 FindFontconfig.cmake [E] [D]
📄 FindFreetype.cmake [E] [D]
📄 FindGCCXML.cmake [E] [D]
📄 FindGDAL.cmake [E] [D]
📄 FindGIF.cmake [E] [D]
📄 FindGLEW.cmake [E] [D]
📄 FindGLU.cmake [E] [D]
📄 FindGLUT.cmake [E] [D]
📄 FindGSL.cmake [E] [D]
📄 FindGTK.cmake [E] [D]
📄 FindGTK2.cmake [E] [D]
📄 FindGTest.cmake [E] [D]
📄 FindGettext.cmake [E] [D]
📄 FindGit.cmake [E] [D]
📄 FindGnuTLS.cmake [E] [D]
📄 FindGnuplot.cmake [E] [D]
📄 FindHDF5.cmake [E] [D]
📄 FindHSPELL.cmake [E] [D]
📄 FindHTMLHelp.cmake [E] [D]
📄 FindHg.cmake [E] [D]
📄 FindICU.cmake [E] [D]
📄 FindIce.cmake [E] [D]
📄 FindIconv.cmake [E] [D]
📄 FindIcotool.cmake [E] [D]
📄 FindImageMagick.cmake [E] [D]
📄 FindIntl.cmake [E] [D]
📄 FindJNI.cmake [E] [D]
📄 FindJPEG.cmake [E] [D]
📄 FindJasper.cmake [E] [D]
📄 FindJava.cmake [E] [D]
📄 FindKDE3.cmake [E] [D]
📄 FindKDE4.cmake [E] [D]
📄 FindLAPACK.cmake [E] [D]
📄 FindLATEX.cmake [E] [D]
📄 FindLTTngUST.cmake [E] [D]
📄 FindLibArchive.cmake [E] [D]
📄 FindLibLZMA.cmake [E] [D]
📄 FindLibXml2.cmake [E] [D]
📄 FindLibXslt.cmake [E] [D]
📄 FindLibinput.cmake [E] [D]
📄 FindLua.cmake [E] [D]
📄 FindLua50.cmake [E] [D]
📄 FindLua51.cmake [E] [D]
📄 FindMFC.cmake [E] [D]
📄 FindMPEG.cmake [E] [D]
📄 FindMPEG2.cmake [E] [D]
📁 FindMPI Open [D]
📄 FindMPI.cmake [E] [D]
📄 FindMatlab.cmake [E] [D]
📄 FindMotif.cmake [E] [D]
📄 FindODBC.cmake [E] [D]
📄 FindOpenACC.cmake [E] [D]
📄 FindOpenAL.cmake [E] [D]
📄 FindOpenCL.cmake [E] [D]
📄 FindOpenGL.cmake [E] [D]
📄 FindOpenMP.cmake [E] [D]
📄 FindOpenSSL.cmake [E] [D]
📄 FindOpenSceneGraph.cmake [E] [D]
📄 FindOpenThreads.cmake [E] [D]
📄 FindPHP4.cmake [E] [D]
📄 FindPNG.cmake [E] [D]
📄 FindPackageHandleStandardArgs.cmake [E] [D]
📄 FindPackageMessage.cmake [E] [D]
📄 FindPatch.cmake [E] [D]
📄 FindPerl.cmake [E] [D]
📄 FindPerlLibs.cmake [E] [D]
📄 FindPhysFS.cmake [E] [D]
📄 FindPike.cmake [E] [D]
📄 FindPkgConfig.cmake [E] [D]
📄 FindPostgreSQL.cmake [E] [D]
📄 FindProducer.cmake [E] [D]
📄 FindProtobuf.cmake [E] [D]
📁 FindPython Open [D]
📄 FindPython.cmake [E] [D]
📄 FindPython2.cmake [E] [D]
📄 FindPython3.cmake [E] [D]
📄 FindPythonInterp.cmake [E] [D]
📄 FindPythonLibs.cmake [E] [D]
📄 FindQt.cmake [E] [D]
📄 FindQt3.cmake [E] [D]
📄 FindQt4.cmake [E] [D]
📄 FindQuickTime.cmake [E] [D]
📄 FindRTI.cmake [E] [D]
📄 FindRuby.cmake [E] [D]
📄 FindRuby.cmake.findruby [E] [D]
📄 FindSDL.cmake [E] [D]
📄 FindSDL_image.cmake [E] [D]
📄 FindSDL_mixer.cmake [E] [D]
📄 FindSDL_net.cmake [E] [D]
📄 FindSDL_sound.cmake [E] [D]
📄 FindSDL_ttf.cmake [E] [D]
📄 FindSQLite3.cmake [E] [D]
📄 FindSWIG.cmake [E] [D]
📄 FindSelfPackers.cmake [E] [D]
📄 FindSquish.cmake [E] [D]
📄 FindSubversion.cmake [E] [D]
📄 FindTCL.cmake [E] [D]
📄 FindTIFF.cmake [E] [D]
📄 FindTclStub.cmake [E] [D]
📄 FindTclsh.cmake [E] [D]
📄 FindThreads.cmake [E] [D]
📄 FindUnixCommands.cmake [E] [D]
📄 FindVulkan.cmake [E] [D]
📄 FindWget.cmake [E] [D]
📄 FindWish.cmake [E] [D]
📄 FindX11.cmake [E] [D]
📄 FindXCTest.cmake [E] [D]
📄 FindXMLRPC.cmake [E] [D]
📄 FindXalanC.cmake [E] [D]
📄 FindXercesC.cmake [E] [D]
📄 FindZLIB.cmake [E] [D]
📄 Findosg.cmake [E] [D]
📄 FindosgAnimation.cmake [E] [D]
📄 FindosgDB.cmake [E] [D]
📄 FindosgFX.cmake [E] [D]
📄 FindosgGA.cmake [E] [D]
📄 FindosgIntrospection.cmake [E] [D]
📄 FindosgManipulator.cmake [E] [D]
📄 FindosgParticle.cmake [E] [D]
📄 FindosgPresentation.cmake [E] [D]
📄 FindosgProducer.cmake [E] [D]
📄 FindosgQt.cmake [E] [D]
📄 FindosgShadow.cmake [E] [D]
📄 FindosgSim.cmake [E] [D]
📄 FindosgTerrain.cmake [E] [D]
📄 FindosgText.cmake [E] [D]
📄 FindosgUtil.cmake [E] [D]
📄 FindosgViewer.cmake [E] [D]
📄 FindosgVolume.cmake [E] [D]
📄 FindosgWidget.cmake [E] [D]
📄 Findosg_functions.cmake [E] [D]
📄 FindwxWidgets.cmake [E] [D]
📄 FindwxWindows.cmake [E] [D]
📁 FortranCInterface Open [D]
📄 FortranCInterface.cmake [E] [D]
📄 GNUInstallDirs.cmake [E] [D]
📄 GenerateExportHeader.cmake [E] [D]
📄 GetPrerequisites.cmake [E] [D]
📄 GoogleTest.cmake [E] [D]
📄 GoogleTestAddTests.cmake [E] [D]
📄 ITKCompatibility.cmake [E] [D]
📄 InstallRequiredSystemLibraries.cmake [E] [D]
📁 IntelVSImplicitPath Open [D]
📁 Internal Open [D]
📄 KDE3Macros.cmake [E] [D]
📄 MacOSXBundleInfo.plist.in [E] [D]
📄 MacOSXFrameworkInfo.plist.in [E] [D]
📄 MacroAddFileDependencies.cmake [E] [D]
📄 MatlabTestsRedirect.cmake [E] [D]
📁 Platform Open [D]
📄 ProcessorCount.cmake [E] [D]
📄 Qt4ConfigDependentSettings.cmake [E] [D]
📄 Qt4Macros.cmake [E] [D]
📄 RepositoryInfo.txt.in [E] [D]
📄 SelectLibraryConfigurations.cmake [E] [D]
📄 Squish4RunTestCase.bat [E] [D]
📄 Squish4RunTestCase.sh [E] [D]
📄 SquishRunTestCase.bat [E] [D]
📄 SquishRunTestCase.sh [E] [D]
📄 SquishTestScript.cmake [E] [D]
📄 SystemInformation.cmake [E] [D]
📄 SystemInformation.in [E] [D]
📄 TestBigEndian.cmake [E] [D]
📄 TestCXXAcceptsFlag.cmake [E] [D]
📄 TestEndianess.c.in [E] [D]
📄 TestForANSIForScope.cmake [E] [D]
📄 TestForANSIStreamHeaders.cmake [E] [D]
📄 TestForANSIStreamHeaders.cxx [E] [D]
📄 TestForAnsiForScope.cxx [E] [D]
📄 TestForSSTREAM.cmake [E] [D]
📄 TestForSSTREAM.cxx [E] [D]
📄 TestForSTDNamespace.cmake [E] [D]
📄 TestForSTDNamespace.cxx [E] [D]
📄 UseEcos.cmake [E] [D]
📄 UseJava.cmake [E] [D]
📄 UseJavaClassFilelist.cmake [E] [D]
📄 UseJavaSymlinks.cmake [E] [D]
📄 UsePkgConfig.cmake [E] [D]
📄 UseQt4.cmake [E] [D]
📁 UseSWIG Open [D]
📄 UseSWIG.cmake [E] [D]
📄 Use_wxWindows.cmake [E] [D]
📄 UsewxWidgets.cmake [E] [D]
📄 VTKCompatibility.cmake [E] [D]
📄 WriteBasicConfigVersionFile.cmake [E] [D]
📄 WriteCompilerDetectionHeader.cmake [E] [D]
📄 ecos_clean.cmake [E] [D]
📄 exportheader.cmake.in [E] [D]
📄 javaTargets.cmake.in [E] [D]
📄 kde3init_dummy.cpp.in [E] [D]
📄 kde3uic.cmake [E] [D]
📄 readme.txt [E] [D]

Editing: FindPostgreSQL.cmake

# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

#[=======================================================================[.rst:
FindPostgreSQL
--------------

Find the PostgreSQL installation.

IMPORTED Targets
^^^^^^^^^^^^^^^^

This module defines :prop_tgt:`IMPORTED` target ``PostgreSQL::PostgreSQL``
if PostgreSQL has been found.

Result Variables
^^^^^^^^^^^^^^^^

This module will set the following variables in your project:

``PostgreSQL_FOUND``
  True if PostgreSQL is found.
``PostgreSQL_LIBRARIES``
  the PostgreSQL libraries needed for linking
``PostgreSQL_INCLUDE_DIRS``
  the directories of the PostgreSQL headers
``PostgreSQL_LIBRARY_DIRS``
  the link directories for PostgreSQL libraries
``PostgreSQL_VERSION_STRING``
  the version of PostgreSQL found
#]=======================================================================]

# ----------------------------------------------------------------------------
# History:
# This module is derived from the module originally found in the VTK source tree.
#
# ----------------------------------------------------------------------------
# Note:
# PostgreSQL_ADDITIONAL_VERSIONS is a variable that can be used to set the
# version number of the implementation of PostgreSQL.
# In Windows the default installation of PostgreSQL uses that as part of the path.
# E.g C:\Program Files\PostgreSQL\8.4.
# Currently, the following version numbers are known to this module:
# "11" "10" "9.6" "9.5" "9.4" "9.3" "9.2" "9.1" "9.0" "8.4" "8.3" "8.2" "8.1" "8.0"
#
# To use this variable just do something like this:
# set(PostgreSQL_ADDITIONAL_VERSIONS "9.2" "8.4.4")
# before calling find_package(PostgreSQL) in your CMakeLists.txt file.
# This will mean that the versions you set here will be found first in the order
# specified before the default ones are searched.
#
# ----------------------------------------------------------------------------
# You may need to manually set:
#  PostgreSQL_INCLUDE_DIR  - the path to where the PostgreSQL include files are.
#  PostgreSQL_LIBRARY_DIR  - The path to where the PostgreSQL library files are.
# If FindPostgreSQL.cmake cannot find the include files or the library files.
#
# ----------------------------------------------------------------------------
# The following variables are set if PostgreSQL is found:
#  PostgreSQL_FOUND         - Set to true when PostgreSQL is found.
#  PostgreSQL_INCLUDE_DIRS  - Include directories for PostgreSQL
#  PostgreSQL_LIBRARY_DIRS  - Link directories for PostgreSQL libraries
#  PostgreSQL_LIBRARIES     - The PostgreSQL libraries.
#
# The ``PostgreSQL::PostgreSQL`` imported target is also created.
#
# ----------------------------------------------------------------------------
# If you have installed PostgreSQL in a non-standard location.
# (Please note that in the following comments, it is assumed that <Your Path>
# points to the root directory of the include directory of PostgreSQL.)
# Then you have three options.
# 1) After CMake runs, set PostgreSQL_INCLUDE_DIR to <Your Path>/include and
#    PostgreSQL_LIBRARY_DIR to wherever the library pq (or libpq in windows) is
# 2) Use CMAKE_INCLUDE_PATH to set a path to <Your Path>/PostgreSQL<-version>. This will allow find_path()
#    to locate PostgreSQL_INCLUDE_DIR by utilizing the PATH_SUFFIXES option. e.g. In your CMakeLists.txt file
#    set(CMAKE_INCLUDE_PATH ${CMAKE_INCLUDE_PATH} "<Your Path>/include")
# 3) Set an environment variable called ${PostgreSQL_ROOT} that points to the root of where you have
#    installed PostgreSQL, e.g. <Your Path>.
#
# ----------------------------------------------------------------------------

set(PostgreSQL_INCLUDE_PATH_DESCRIPTION "top-level directory containing the PostgreSQL include directories. E.g /usr/local/include/PostgreSQL/8.4 or C:/Program Files/PostgreSQL/8.4/include")
set(PostgreSQL_INCLUDE_DIR_MESSAGE "Set the PostgreSQL_INCLUDE_DIR cmake cache entry to the ${PostgreSQL_INCLUDE_PATH_DESCRIPTION}")
set(PostgreSQL_LIBRARY_PATH_DESCRIPTION "top-level directory containing the PostgreSQL libraries.")
set(PostgreSQL_LIBRARY_DIR_MESSAGE "Set the PostgreSQL_LIBRARY_DIR cmake cache entry to the ${PostgreSQL_LIBRARY_PATH_DESCRIPTION}")
set(PostgreSQL_ROOT_DIR_MESSAGE "Set the PostgreSQL_ROOT system variable to where PostgreSQL is found on the machine E.g C:/Program Files/PostgreSQL/8.4")

set(PostgreSQL_KNOWN_VERSIONS ${PostgreSQL_ADDITIONAL_VERSIONS}
    "12" "11" "10" "9.6" "9.5" "9.4" "9.3" "9.2" "9.1" "9.0" "8.4" "8.3" "8.2" "8.1" "8.0")

# Define additional search paths for root directories.
set( PostgreSQL_ROOT_DIRECTORIES
   ENV PostgreSQL_ROOT
   ${PostgreSQL_ROOT}
)
foreach(suffix ${PostgreSQL_KNOWN_VERSIONS})
  if(WIN32)
    list(APPEND PostgreSQL_LIBRARY_ADDITIONAL_SEARCH_SUFFIXES
        "PostgreSQL/${suffix}/lib")
    list(APPEND PostgreSQL_INCLUDE_ADDITIONAL_SEARCH_SUFFIXES
        "PostgreSQL/${suffix}/include")
    list(APPEND PostgreSQL_TYPE_ADDITIONAL_SEARCH_SUFFIXES
        "PostgreSQL/${suffix}/include/server")
  endif()
  if(UNIX)
    list(APPEND PostgreSQL_LIBRARY_ADDITIONAL_SEARCH_SUFFIXES
        "postgresql${suffix}"
        "pgsql-${suffix}/lib")
    list(APPEND PostgreSQL_INCLUDE_ADDITIONAL_SEARCH_SUFFIXES
        "postgresql${suffix}"
        "postgresql/${suffix}"
        "pgsql-${suffix}/include")
    list(APPEND PostgreSQL_TYPE_ADDITIONAL_SEARCH_SUFFIXES
        "postgresql${suffix}/server"
        "postgresql/${suffix}/server"
        "pgsql-${suffix}/include/server")
  endif()
endforeach()

#
# Look for an installation.
#
find_path(PostgreSQL_INCLUDE_DIR
  NAMES libpq-fe.h
  PATHS
   # Look in other places.
   ${PostgreSQL_ROOT_DIRECTORIES}
  PATH_SUFFIXES
    pgsql
    postgresql
    include
    ${PostgreSQL_INCLUDE_ADDITIONAL_SEARCH_SUFFIXES}
  # Help the user find it if we cannot.
  DOC "The ${PostgreSQL_INCLUDE_DIR_MESSAGE}"
)

find_path(PostgreSQL_TYPE_INCLUDE_DIR
  NAMES catalog/pg_type.h
  PATHS
   # Look in other places.
   ${PostgreSQL_ROOT_DIRECTORIES}
  PATH_SUFFIXES
    postgresql
    pgsql/server
    postgresql/server
    include/server
    ${PostgreSQL_TYPE_ADDITIONAL_SEARCH_SUFFIXES}
  # Help the user find it if we cannot.
  DOC "The ${PostgreSQL_INCLUDE_DIR_MESSAGE}"
)

# The PostgreSQL library.
set (PostgreSQL_LIBRARY_TO_FIND pq)
# Setting some more prefixes for the library
set (PostgreSQL_LIB_PREFIX "")
if ( WIN32 )
  set (PostgreSQL_LIB_PREFIX ${PostgreSQL_LIB_PREFIX} "lib")
  set (PostgreSQL_LIBRARY_TO_FIND ${PostgreSQL_LIB_PREFIX}${PostgreSQL_LIBRARY_TO_FIND})
endif()

function(__postgresql_find_library _name)
  find_library(${_name}
   NAMES ${ARGN}
   PATHS
     ${PostgreSQL_ROOT_DIRECTORIES}
   PATH_SUFFIXES
     lib
     ${PostgreSQL_LIBRARY_ADDITIONAL_SEARCH_SUFFIXES}
   # Help the user find it if we cannot.
   DOC "The ${PostgreSQL_LIBRARY_DIR_MESSAGE}"
  )
endfunction()

# For compatibility with versions prior to this multi-config search, honor
# any PostgreSQL_LIBRARY that is already specified and skip the search.
if(PostgreSQL_LIBRARY)
  set(PostgreSQL_LIBRARIES "${PostgreSQL_LIBRARY}")
  get_filename_component(PostgreSQL_LIBRARY_DIR "${PostgreSQL_LIBRARY}" PATH)
else()
  __postgresql_find_library(PostgreSQL_LIBRARY_RELEASE ${PostgreSQL_LIBRARY_TO_FIND})
  __postgresql_find_library(PostgreSQL_LIBRARY_DEBUG ${PostgreSQL_LIBRARY_TO_FIND}d)
  include(${CMAKE_CURRENT_LIST_DIR}/SelectLibraryConfigurations.cmake)
  select_library_configurations(PostgreSQL)
  mark_as_advanced(PostgreSQL_LIBRARY_RELEASE PostgreSQL_LIBRARY_DEBUG)
  if(PostgreSQL_LIBRARY_RELEASE)
    get_filename_component(PostgreSQL_LIBRARY_DIR "${PostgreSQL_LIBRARY_RELEASE}" PATH)
  elseif(PostgreSQL_LIBRARY_DEBUG)
    get_filename_component(PostgreSQL_LIBRARY_DIR "${PostgreSQL_LIBRARY_DEBUG}" PATH)
  else()
    set(PostgreSQL_LIBRARY_DIR "")
  endif()
endif()

if (PostgreSQL_INCLUDE_DIR)
  # Some platforms include multiple pg_config.hs for multi-lib configurations
  # This is a temporary workaround.  A better solution would be to compile
  # a dummy c file and extract the value of the symbol.
  file(GLOB _PG_CONFIG_HEADERS "${PostgreSQL_INCLUDE_DIR}/pg_config*.h")
  foreach(_PG_CONFIG_HEADER ${_PG_CONFIG_HEADERS})
    if(EXISTS "${_PG_CONFIG_HEADER}")
      file(STRINGS "${_PG_CONFIG_HEADER}" pgsql_version_str
           REGEX "^#define[\t ]+PG_VERSION_NUM[\t ]+.*")
      if(pgsql_version_str)
        string(REGEX REPLACE "^#define[\t ]+PG_VERSION_NUM[\t ]+([0-9]*).*"
               "\\1" _PostgreSQL_VERSION_NUM "${pgsql_version_str}")
        break()
      endif()
    endif()
  endforeach()
  if (_PostgreSQL_VERSION_NUM)
    # 9.x and older encoding
    if (_PostgreSQL_VERSION_NUM LESS 100000)
      math(EXPR _PostgreSQL_major_version "${_PostgreSQL_VERSION_NUM} / 10000")
      math(EXPR _PostgreSQL_minor_version "${_PostgreSQL_VERSION_NUM} % 10000 / 100")
      math(EXPR _PostgreSQL_patch_version "${_PostgreSQL_VERSION_NUM} % 100")
      set(PostgreSQL_VERSION_STRING "${_PostgreSQL_major_version}.${_PostgreSQL_minor_version}.${_PostgreSQL_patch_version}")
      unset(_PostgreSQL_major_version)
      unset(_PostgreSQL_minor_version)
      unset(_PostgreSQL_patch_version)
    else ()
      math(EXPR _PostgreSQL_major_version "${_PostgreSQL_VERSION_NUM} / 10000")
      math(EXPR _PostgreSQL_minor_version "${_PostgreSQL_VERSION_NUM} % 10000")
      set(PostgreSQL_VERSION_STRING "${_PostgreSQL_major_version}.${_PostgreSQL_minor_version}")
      unset(_PostgreSQL_major_version)
      unset(_PostgreSQL_minor_version)
    endif ()
  else ()
    foreach(_PG_CONFIG_HEADER ${_PG_CONFIG_HEADERS})
      if(EXISTS "${_PG_CONFIG_HEADER}")
        file(STRINGS "${_PG_CONFIG_HEADER}" pgsql_version_str
             REGEX "^#define[\t ]+PG_VERSION[\t ]+\".*\"")
        if(pgsql_version_str)
          string(REGEX REPLACE "^#define[\t ]+PG_VERSION[\t ]+\"([^\"]*)\".*"
                 "\\1" PostgreSQL_VERSION_STRING "${pgsql_version_str}")
          break()
        endif()
      endif()
    endforeach()
  endif ()
  unset(_PostgreSQL_VERSION_NUM)
  unset(pgsql_version_str)
endif()

# Did we find anything?
include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
find_package_handle_standard_args(PostgreSQL
                                  REQUIRED_VARS PostgreSQL_LIBRARY PostgreSQL_INCLUDE_DIR PostgreSQL_TYPE_INCLUDE_DIR
                                  VERSION_VAR PostgreSQL_VERSION_STRING)
set(PostgreSQL_FOUND  ${POSTGRESQL_FOUND})

function(__postgresql_import_library _target _var _config)
  if(_config)
    set(_config_suffix "_${_config}")
  else()
    set(_config_suffix "")
  endif()

set(_lib "${${_var}${_config_suffix}}")
  if(EXISTS "${_lib}")
    if(_config)
      set_property(TARGET ${_target} APPEND PROPERTY
        IMPORTED_CONFIGURATIONS ${_config})
    endif()
    set_target_properties(${_target} PROPERTIES
      IMPORTED_LOCATION${_config_suffix} "${_lib}")
  endif()
endfunction()

# Now try to get the include and library path.
if(PostgreSQL_FOUND)
  if (NOT TARGET PostgreSQL::PostgreSQL)
    add_library(PostgreSQL::PostgreSQL UNKNOWN IMPORTED)
    set_target_properties(PostgreSQL::PostgreSQL PROPERTIES
      INTERFACE_INCLUDE_DIRECTORIES "${PostgreSQL_INCLUDE_DIR};${PostgreSQL_TYPE_INCLUDE_DIR}")
    __postgresql_import_library(PostgreSQL::PostgreSQL PostgreSQL_LIBRARY "")
    __postgresql_import_library(PostgreSQL::PostgreSQL PostgreSQL_LIBRARY "RELEASE")
    __postgresql_import_library(PostgreSQL::PostgreSQL PostgreSQL_LIBRARY "DEBUG")
  endif ()
  set(PostgreSQL_INCLUDE_DIRS ${PostgreSQL_INCLUDE_DIR} ${PostgreSQL_TYPE_INCLUDE_DIR} )
  set(PostgreSQL_LIBRARY_DIRS ${PostgreSQL_LIBRARY_DIR} )
endif()

mark_as_advanced(PostgreSQL_INCLUDE_DIR PostgreSQL_TYPE_INCLUDE_DIR)